netcdf.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# Copyright (c) 2024 - 2025 Antoine Morvan
# Copyright (c) 2024 Niclas Schroeter
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY netcdf_help_string "Enable netcdf project")
set_property(GLOBAL PROPERTY netcdf_can_use_system TRUE)
set_property(GLOBAL PROPERTY netcdf_depends hdf5)
 
if(DEFINED netcdf_configure_args)
  message( FATAL_ERROR
    "NetCDF recipe in HPCW has been updated to use CMake instead of configure script."
    "Hence, \${netcdf_cmake_args} is used instead of \${netcdf_configure_args}."
    "We have detected that you are still using \${netcdf_configure_args}, which now triggers this error."
    "Please update your scripts and/or toolchains to update the build flags accordingly and define \${netcdf_cmake_args}.")
endif()
set(netcdf_cmake_args "" CACHE STRING "Custom CMake arguments for NetCDF")
set(netcdf_build_args "" CACHE STRING "Custom Make arguments for NetCDF")
 
if(netcdf_enabled)
  if(USE_SYSTEM_netcdf)
    message(STATUS "NETCDF: enabled (system installed)")
    enable_language(Fortran)
    find_package(
      NetCDF
      COMPONENTS C;Fortran
      REQUIRED)
 
    message(STATUS "NETCDF_DIR: ${NETCDF_DIR}")
    message(STATUS "NETCDFF_DIR: ${NETCDFF_DIR}")
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" ${NETCDF_DIR}/include)
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                       "${NETCDF_DIR}/lib")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                       "${NETCDF_DIR}/lib")
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${NETCDF_DIR}/bin")
 
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" ${NETCDFF_DIR}/include)
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                       "${NETCDFF_DIR}/lib")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                       "${NETCDFF_DIR}/lib")
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${NETCDFF_DIR}/bin")
 
  else()
 
    if(NOT TARGET netcdf::C)
      message(STATUS "NETCDF: enabled (internally built)")
 
      set(netcdf_depends_ep hdf5::hdf5_hl)
      if(mpi_enabled)
        list(APPEND netcdf_depends_ep MPI::MPI_C)
      endif()
 
      if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
        if (NOT CMAKE_C_COMPILER_VERSION VERSION_LESS 15)
          string(APPEND NETCDF_C_FLAGS "-std=gnu17")
        endif()
      endif()
 
      ExternalProject_Data_Add(
        netcdf-c
        ${netcdf-c_revision}
        DEPENDS ${netcdf_depends_ep}
        PATCH_COMMAND ${CMAKE_SOURCE_DIR}/bin/patchShebangs <SOURCE_DIR> ||
                          true
 
        CMAKE_ARGS ${cmake_params}
          -Wno-dev
          -DCMAKE_INSTALL_LIBDIR:FILEPATH=lib
          -DCMAKE_INSTALL_PREFIX:FILEPATH=<INSTALL_DIR>
          -DCMAKE_BUILD_TYPE:STRING=Release
          -DBUILD_SHARED_LIBS:BOOL=ON
          -DBUILD_STATIC_LIBS:BOOL=ON
          -DNETCDF_ENABLE_DOXYGEN=OFF
          -DNETCDF_ENABLE_TESTS=OFF
          -DNETCDF_ENABLE_PARALLEL_TESTS=OFF
          -DNETCDF_ENABLE_LARGE_FILE_SUPPORT=ON
          -DNETCDF_ENABLE_FILTER_BZ2=OFF
          -DNETCDF_ENABLE_HDF5=ON # as stated in the NetCDF CMakeList.txt : "NETCDF_ENABLE_NETCDF4 is deprecated; please use NETCDF_ENABLE_HDF5"
          ${default_cmake_args}
          ${netcdf_cmake_args}
        BUILD_COMMAND   ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${netcdf_build_args}
        INSTALL_COMMAND ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} PREFIX=<INSTALL_DIR> install
      )
 
      ExternalProject_Get_Property(netcdf-c INSTALL_DIR)
      set(NETCDF_DIR ${INSTALL_DIR})
      message(STATUS "NETCDF_DIR: ${NETCDF_DIR}")
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${NETCDF_DIR}/include")
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}"
                         "${NETCDF_DIR}/include/shared")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                         "${NETCDF_DIR}/lib")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                         "${NETCDF_DIR}/lib")
      set_if_not_present(ENV{PATH} "$ENV{PATH}" "${NETCDF_DIR}/bin")
 
      add_library(netcdf::C INTERFACE IMPORTED)
      set_property(
        TARGET netcdf::C PROPERTY INTERFACE_LINK_LIBRARIES
                                  ${NETCDF_DIR}/lib/libnetcdf.a hdf5::hdf5_hl)
      set_property(TARGET netcdf::C PROPERTY INTERFACE_INCLUDE_DIRECTORIES
                                             "${NETCDF_DIR}/include")
      add_dependencies(netcdf::C netcdf-c)
      enable_language(Fortran)
      string(APPEND NETCDF_FORTRAN_FLAGS "-fPIC")
      if(CMAKE_Fortran_COMPILER_ID STREQUAL "Cray")
        string(APPEND NETCDF_FORTRAN_FLAGS " -ef")
      endif()
      if(CMAKE_Fortran_COMPILER_ID STREQUAL "GNU")
        if (NOT CMAKE_Fortran_COMPILER_VERSION VERSION_LESS 11)
          string(APPEND NETCDF_FORTRAN_FLAGS " -fallow-argument-mismatch")
        endif()
      endif()
 
      ExternalProject_Data_Add(
        netcdf-fortran
        DEPENDS netcdf-c ${netcdf-fortran_revision}
 
        CMAKE_ARGS ${cmake_params}
          -Wno-dev
          -DCMAKE_INSTALL_LIBDIR:FILEPATH=lib
          -DCMAKE_INSTALL_PREFIX:FILEPATH=<INSTALL_DIR>
          -DCMAKE_BUILD_TYPE:STRING=Release
          -DBUILD_SHARED_LIBS:BOOL=ON
          -DBUILD_STATIC_LIBS:BOOL=ON
          -DNETCDF_ENABLE_DOXYGEN=OFF
          -DNETCDF_ENABLE_LARGE_FILE_SUPPORT=ON
          -DCMAKE_Fortran_FLAGS='${NETCDF_FORTRAN_FLAGS}'
          ${default_cmake_args}
          ${netcdf_cmake_args}
        BUILD_COMMAND   ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${netcdf_build_args}
        INSTALL_COMMAND ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} PREFIX=<INSTALL_DIR> install
      )
 
      ExternalProject_Get_Property(netcdf-fortran INSTALL_DIR)
      set(NETCDFF_DIR ${INSTALL_DIR})
      message(STATUS "NETCDFF_DIR: ${NETCDFF_DIR}")
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${NETCDFF_DIR}/include")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                         "${NETCDFF_DIR}/lib")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                         "${NETCDFF_DIR}/lib")
      set_if_not_present(ENV{PATH} "$ENV{PATH}" "${NETCDFF_DIR}/bin")
 
      add_library(netcdf::Fortran INTERFACE IMPORTED)
      set_property(
        TARGET netcdf::Fortran
        PROPERTY INTERFACE_LINK_LIBRARIES ${NETCDFF_DIR}/lib/libnetcdff.a
                 netcdf::C)
      set_property(TARGET netcdf::Fortran PROPERTY INTERFACE_INCLUDE_DIRECTORIES
                                                   "${NETCDFF_DIR}/include")
      add_dependencies(netcdf::Fortran netcdf-fortran)
    endif()
  endif()
endif()